***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Nov 29, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PJGBLC24 A K
.param
+vc0 = 6.846e-9		vc1 = 5.306e-10		vc2 = 7.200e-1		vc3 = 1.013e-10		vc4 = 1.005e-2
+tc1 = 1.181e-1		tc2 = 3.505e-2		tc3 = 9.708e-2		tc4 = 6.755e-2
.func irexp(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1
***** dc model parameter *****
+ is = 1.036e-13	   n = 1.078		  rs = 1.156e-0		 ikf = 3e-3
+ibv = 1e-3		 nbv = 3.0		  bv = 28.71
***** capacitance parameter *****
+cjo = 8.266e-13	   m = 2.004e-2		  vj = 3.905e-1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.117		 xti = 3
+trs1 = 1.445e-3	trs2 = 5.806e-6		tikf = 5e-3
+tbv1 = 7.287e-4	tbv2 = -1.755e-7
.ends PJGBLC24
*$
